"=============================================================================
" Macros for editing vhdl code.
" Author : M A Aziz Ahmed (aziz@123india.com)
" Last update : Tue Apr 20 1999
" Contents :
"   Settings
"   General shortcut keys
"   Columnizing macros
"     To make your VHDL code look better.
"   Timing diagram macros
"     Draw timing diagrams in your comments to make your code more readable.
"   Macros to convert all keywords to small or to caps.
" Tested with :
"   GVim-5.3 under Windows 95.
"=============================================================================


"=============================================================================
" Settings for editing VHDL files.
"=============================================================================
set nocindent
set autoindent
set smartindent
set cinwords=if,else,elsif,case,while,for,begin,when

"=============================================================================
" General shortcut keys.
" BTW, the keywords are all lower case! Modify it according to your needs or 
" use my macros to convert all keywords to caps or small.
"=============================================================================
  iab st      std_logic ;
  iab sv      std_logic_vector ( downto 0) ;<ESC>11hi
  iab sti     in    std_logic ;
  iab sto     out   std_logic ;
  iab sio     inout std_logic ;
  iab siv     in    std_logic_vector ( downto 0) ;<ESC>11hi
  iab sov     out   std_logic_vector ( downto 0) ;<ESC>11hi
  iab siov    inout std_logic_vector ( downto 0) ;<ESC>11hi
  iab sg      signal
  iab dt      downto
  iab vr      variable
  iab ot      (others => '0') ;
  iab cc      -----------------------------------------------------------------------------
  
  iab vpr     <label> : process()<C-M>begin<C-M>end process <label> ;<ESC>O	<ESC>:call ProcLabel()
  iab vfo     <label> : for i in  to  loop<C-M>end loop <label> ;<ESC>k:call ForLabel()
  iab iff     if () then<C-M>end if ;<ESC>k0%
  iab ifel    if () then<C-M>else<C-M>end if ;<ESC>2k0%
  iab vcas    case  is<C-M>	when  =><C-M>when  =><C-M>when others =><C-M><C-H>end case ;<ESC>4k2h
  iab ast     assert ()<C-M>	report ""<C-M>severity error ;<ESC>kkh
  iab arc     architecture  of  is<C-M>end  ;
  iab ent     entity  is<C-M>	generic<C-M>	(<C-M>) ;<C-M><C-H>port<C-M> (<C-M>) ;<ESC>6kll

  "Commenting lines. Visual select the block required and type ,c. If there is
  " only one line to be commented, visual selection is not required.
  map ,c :s/^/--/

"=============================================================================
" Columnizing macros
" This function columnizes a given character in a range of lines. No change is
" made to the line if the character is not found
" The following set of lines
"      SIGNAL  sig1  :  std_logic ;
"      SIGNAL  sig_from_x_to_y  :  integer ;
"      --this is a comment
"      SIGNAL  s  :  std_logic ;
"      converts to (when columnized with respect to ":"):
"      SIGNAL  sig1             :  std_logic ;
"      SIGNAL  sig_from_x_to_y  :  integer ;
"      --this is a comment
"      SIGNAL  s                :  std_logic ;
"=============================================================================
" Notes :
" 1. The key combination ,f is mapped to columnize with respect to ":" by
"    inserting tabs. It is assumed that you visually select the block before
"    calling this macro.
" 2. The second argument to the function Columnize should be 0 if you want to
"    columnize by inserting spaces.
" 3. You can also use this function to columnize port-mappings :
"      port map (
"          x => y ,
"          longsignal_name => z
"          ) ;
"     can be easily made
"      port map (
"          x               => y ,
"          longsignal_name => z
"          ) ;
"=============================================================================
vmap ,f :call ColumnizeChar(":",1)

function! ColumnizeChar(separator, useTabs) range
  "First job is to find the line where the separator is the farthest.
  let maxLine = a:firstline
  let cur = a:firstline
  let maxCol = 0
  while(cur <= a:lastline)
    " First go to the separator
    execute(cur)
    exe "normal 0f".a:separator
    let currCol = virtcol(".")
    if( currCol > maxCol)
      let maxCol = currCol
      let maxLine = cur
    endif
    let cur = cur + 1
  endwhile	
  " If tabs are to be used maxCol should be a multiple of tabstop + 1
  let tabStop = &tabstop
  if ((a:useTabs==1) && (maxCol%tabStop!=1) && (tabStop!=1))
    let debugPurp = maxCol
    let maxCol = maxCol + tabStop - ((maxCol-1)%tabStop)
    echo "Columnizing from ".debugPurp."till ".maxCol
  endif
  "Now the line with the farthest separator is given by maxLine.
  "Next job is to modify all lines so that the separator position matches with the farthest.
  "Avoid substitution reports..
  let oldReport = &report
  let &report = 1000
  let cur = a:firstline
  while (cur <= a:lastline)
    "go to the line.
    execute(cur)
    if( match(getline("."),a:separator) >= 0)
      execute "normal 0f".a:separator
      let curColPos = virtcol(".")
      while(curColPos < maxCol)
        if (a:useTabs==1)
          execute "s/".a:separator."/	".a:separator."/e"
        else
          execute "s/".a:separator."/ ".a:separator."/e"
        endif
        execute "normal 0f".a:separator
        let curColPos = virtcol(".")
      endwhile
    endif
    let cur = cur + 1
  endwhile
  let &report = oldReport
endfunction



"=============================================================================
" Timing diagram macros. 
" ,p creates clock. Other signals when described with
" 0s and 1s can be operated upon with ,w in command mode to produce a diagram
" based upon this clock.	" based ,
" Example :
" clk       __/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__  
" sig1      00110101
" when ,w is typed with the cursor in the second line (the line with "sig1") :
" 
" clk       __/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__  
" sig1      ___________/~~~~~~~~~~~\_____/~~~~~\_____/~~~~~
"
" I use these waveforms as comments in my code to explain some complicated
" timing.
" Note : it is required for the following macro that the waveform description
" 00110101 cannot be the beginning of the line.
"=============================================================================
nmap ,p i__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__/~~\__
nmap ,w :s;\([^a-zA-Z2-9_]\)0;\1_____/;ge:s;\([^a-zA-Z2-9_]\)1;\1\~\~\~\~\~\\;ge:s;\([^a-zA-Z2-9_]\)0;\1_____/;ge:s;\([^a-zA-Z2-9_]\)1;\1\~\~\~\~\~\\;ge:s;/_;__;ge:s;\\\~;\~\~;ge:s;.$;;e


"=============================================================================
" Auxiliary functions used in abbreviations
"=============================================================================
  function! ProcLabel()
    normal mt
    let label = input("Enter a name for the process : ")
    execute "-2,+1 s/<label>/".label."/"
    normal `t
  endfunction

  function! ForLabel()
    normal mt
    let label = input("Enter a label for the for loop : ")
    execute ".,+ s/<label>/".label."/"
    normal `t
  endfunction